AHK关掉恼人的微信电脑语音视频电话弹窗

我发现微信电脑端（测试的时候是4.1.6.46）有一个很讨厌的问题，就是一旦别人视频或者语音电话给你，你的的右下角就会有一个弹窗，而且离谱的时候，我在设置中，根本关不掉。

当然这里书都关不掉指的是，我查了各种资料，做了包括不限于如下的操作

找windows10里的信息通知（没找到）
消息列表中设置仅限闹钟
windows防火墙限制微信的UDP

最后借助AI的力量，用最传统的方法，实时监控电脑，一旦看到弹窗给它瞬间隐藏。

第一步，安装AHK，这是他的官方站点https://www.autohotkey.com/ （记得之前用这个软件还是为DNF连招）

第二步，新建一个脚本，命名为 wechat_call_popup_kill.ahk, 粘贴如下的代码，并保存。

#Requires AutoHotkey v2.0
#SingleInstance Force

SetTimer BlockWeChatCallPopup, 80
DetectHiddenWindows false

; 你的来电小窗尺寸（允许一点点误差）
global TARGET_W := 472
global TARGET_H := 170
global TOL_W := 30
global TOL_H := 30

; 右下角容差（像素）
global EDGE_PAD := 120

BlockWeChatCallPopup() {
    for hwnd in WinGetList("ahk_exe Weixin.exe") {
        try {
            if (WinGetClass("ahk_id " hwnd) != "Qt51514QWindowIcon")
                continue

            WinGetPos &x, &y, &w, &h, "ahk_id " hwnd

            ; 尺寸匹配（来电小窗）
            if (Abs(w - TARGET_W) > TOL_W || Abs(h - TARGET_H) > TOL_H)
                continue

            ; 位置匹配（贴近主屏右下角工作区）
            mon := MonitorGetPrimary()
            MonitorGetWorkArea mon, &L, &T, &R, &B
            rightGap  := R - (x + w)
            bottomGap := B - (y + h)
            if (rightGap > EDGE_PAD || bottomGap > EDGE_PAD)
                continue

            ; 最稳：隐藏（避免 WinClose 无效/闪烁）
            WinHide "ahk_id " hwnd

            ; 如果你更希望“直接关掉窗口”，用下面替换 WinHide：
            ; PostMessage 0x0010, 0, 0, , "ahk_id " hwnd   ; WM_CLOSE
        }
    }
}

第三步，双击运行。启动后，别人打电话给你，手机端依旧会有提示，电脑端只会一闪而过。

此外还可以设置开机自动运行。使用快捷键Win + R → 输入 shell:startup → 回车，将脚本放进去。